$ontext

  classification through linear programming

  Reference:
     O. L. Mangasarian, W. N. Street, and W. W. Wolberg,
     "Breast Cancer Diagnosis and Prognosis Via Linear Programming,"
     Operations Research. 43 (1995), 570-577

  Data from http://cgm.cs.mcgill.ca/~beezer/cs644/example.html

$offtext


set
  d '2d dataset' /x,y/
  i 'cases for points A' /i1*i13/
  j 'cases for points B' /j1*j17/
;


table pa(i,d)
      x    y
 i1   3    1
 i2   2    2
 i3   4    3
 i4   3    4
 i5   0    5
 i6   1    5
 i7   5    5
 i8   1    6
 i9   2    7
 i10  3    7
 i11  1    8
 i12  0    9
 i13  2   10
;

table pb(j,d)
      x    y
 j1   9    0
 j2  10    0
 j3  10    1
 j4  10    3
 j5   8    4
 j6  12    4
 j7   9    5
 j8  11    5
 j9   6    6
 j10  8    6
 j11 10    6
 j12  8    7
 j13  9    7
 j14  8    8
 j15  5    8
 j16  5    9
 j17  7    9
;

scalar n,m;
n = card(i);
m = card(j);

variables obj,gamma,w(d);
positive variables y(i),z(j);
equations objdef,eqa(i),eqb(j);

objdef.. obj =e= sum(i,y(i))/n + sum(j,z(j))/m;
eqa(i).. sum(d,pa(i,d)*w(d)) + y(i) =g= gamma+1;
eqb(j).. sum(d,pb(j,d)*w(d)) - z(j) =l= gamma-1;

model classify /objdef,eqa,eqb/;
solve classify minimizing obj using lp;

display gamma.l,w.l;