$ontext

  Linear Least Squares Regression

  NIST test data

  Erwin kalvelagen, dec 2004

  Reference:
      http://www.itl.nist.gov/div898/strd/lls/lls.shtml

      Eberhardt, K., NIST.

 Model:         Linear Class
               1 Parameter (B1)

               y = B1*x + e




               Certified Regression Statistics

                                          Standard Deviation
     Parameter          Estimate             of Estimate

        B1          2.07438016528926     0.165289256198347E-01

     Residual
     Standard Deviation   3.56753034006338

     R-Squared            0.999365492298663

               Certified Analysis of Variance Table

Source of Degrees of    Sums of             Mean
Variation  Freedom      Squares            Squares          F Statistic

Regression    1    200457.727272727   200457.727272727   15750.2500000000
Residual     10    127.272727272727   12.7272727272727


$offtext

set i 'cases' /i1*i11/;

table data(i,*)
           y     x
  i1     130    60
  i2     131    61
  i3     132    62
  i4     133    63
  i5     134    64
  i6     135    65
  i7     136    66
  i8     137    67
  i9     138    68
  i10    139    69
  i11    140    70
;

*
* note:no constant term
*
$onecho > ls.opt
add_constant_term 0
$offecho

variables
   b1
   sse 'sum of squared errors'
;

equation
   fit(i)    'equation to fit'
   sumsq
;

sumsq..   sse =n= 0;
fit(i)..  data(i,'y') =e= b1*data(i,'x');

option lp = ls;
model leastsq /fit,sumsq/;
leastsq.optfile=1;
solve leastsq using lp minimizing sse;
option decimals=8;
display b1.l;

scalar B1cert /   2.07438016528926   /;

scalar err "Sum of squared errors in estimates";
err = sqr(b1.l-B1cert);
display err;
abort$(err>0.0001) "Solution not accurate";