$ontext

 I have 28 golfers playing over four days in foursomes. I want the best
 combination. I realize not everyone can play together. Anyone with
 help? Thanks

  We minimize here the max number of times players meet each other.
  The optimal objective is one, which means players meet eachother
  zero or one times.


  References:
     - problem 10 in CSPLIB (www.csplib.org)
     - Barbara Smith, "Reducing Symmetry in a Combinatorial
       Design Problem", Tech. Report, School of Computing and
       Mathematics, University of Huddersfield, 2001.


$offtext


set
   t  'days'   /day1*day4/
   i  'golfers' /golfer1*golfer28/
   g  'group'   /group1*group7/
;

alias(i,j);

binary variables    x(i,g,t)      'schedule';
positive variable   meet(i,j,g,t) 'golfer i and j meet';
free variables      maxmeet       'max number of times players meet';

equations
    game(i,t)          'each golver plays one game per week'
    fourplayer(g,t)    'four players per game'
    multiply1(i,j,g,t) 'linearization of multiplication (not used)'
    multiply2(i,j,g,t) 'linearization of multiplication (not used)'
    multiply3(i,j,g,t) 'linearization of multiplication'
    meetcount(i,j)
;

set ij(i,j);
ij(i,j)$(ord(i)>ord(j)) = yes;


*
* golfer plays one game per week
*
game(i,t).. sum(g, x(i,g,t)) =e= 1;

*
* four players per game
*
fourplayer(g,t).. sum(i, x(i,g,t)) =e= 4;

*
* linearization of x(i,g,t)*x(j,g,t)
* Note: we can relax the first two equations multiply1, multiply2
*
multiply1(ij(i,j),g,t).. meet(ij,g,t) =l= x(i,g,t);
multiply2(ij(i,j),g,t).. meet(ij,g,t) =l= x(j,g,t);
multiply3(ij(i,j),g,t).. meet(ij,g,t) =g= x(i,g,t)+x(j,g,t)-1;

meet.lo(ij,g,t) = 0;
meet.up(ij,g,t) = 1;

*
* players i and j can meet only once
*
meetcount(ij(i,j)).. sum((g,t), meet(ij,g,t)) =l= maxmeet;



*
* fix first round
*
set first(i,g) /
  (golfer1*golfer4).group1
  (golfer5*golfer8).group2
  (golfer9*golfer12).group3
  (golfer13*golfer16).group4
  (golfer17*golfer20).group5
  (golfer21*golfer24).group6
  (golfer25*golfer28).group7
/;
x.fx(first,'day1') = 1;

model m /game,fourplayer,multiply3,meetcount/;
solve m minimizing maxmeet using mip;

* check
parameter meetcount2(i,j) "sanity check";
meetcount2(i,j)$(not sameas(i,j)) = round(sum((g,t),x.l(i,g,t)*x.l(j,g,t)));
option meetcount2:0:1:1;
display meetcount2;

options x:0:2:1;
display x.l;