$ontext

   Capacitated warehouse location problem
   Traditional formulation

   Data from:
   http://people.brunel.ac.uk/~mastjjb/jeb/orlib/capinfo.html

$offtext

$include capa.inc

parameter
   demand(j)   'demand for each client'
   cap(i)      'capacity'
   fcost(i)    'fixed cost'
   xcost(i,j)  'variable cost'
;
display custdata;
demand(j) = custdata(j,'demand');
cap(i) = whdata(i,'capacity');
fcost(i) = whdata(i,'fixedcost');
xcost(i,j) = custdata(j,i);
display xcost;

positive variables x(i,j) 'amount shipped';
binary variable y(i) 'facility open/close';
variable cost;

equations
   assign(j)     'assignment constraint'
   capacity(i)   'capacity'
   obj           'objective'
   extra         'this one does not help'
;

x.up(i,j)=cap(i);

obj.. cost =e= sum(i, fcost(i)*y(i)) + sum((i,j),[xcost(i,j)/demand(j)]*x(i,j));

assign(j).. sum(i, x(i,j)) =E= demand(j);

capacity(i).. sum(j, x(i,j)) =L= cap(i)*y(i);

extra(i,j).. x(i,j)=L=min(demand(j),cap(i))*y(i);

option optcr=0;
model m1 /obj,assign,capacity/;
model m2 /obj,assign,capacity,extra/;
solve m1 minimizing cost using mip;

option y:0,x:0;
display y.l, x.l;